VBA Msgbox – A Complete Guide to the VBA Message Box

VBA MsgBox

The VBA MsgBox function is used to display messages to the user in the form of a message box.

 

We can configure the message box to provide the user with a number of different buttons such as Yes, No, Ok, Retry, Abort, Ignore and Cancel. The MsgBox function will then return the button that was clicked.

 

Related Links

VBA Userforms

 

Basic VBA MsgBox Examples

In most cases, you will use MsgBox to simply display a message or to ask the user to click Yes/No or Ok/Cancel. The following code shows how to display a simple message box:

Sub BasicMessageBox()

    ' Basic message
    MsgBox "There is no data on this worksheet "

    ' Basic message with "Error" as the title
    MsgBox "There is no data on this worksheet ", , "Error"

End Sub

 

MsgBox Example

VBA MsgBox Parameters

The parameters of the message box are as follows:

MsgBox prompt, [ buttons, ] [ title, ] [ helpfile, context ]

prompt – This is the message text that will be displayed.

buttons[optional] – This parameter does many things including setting the buttons, icons, select button, modal type etc. If this parameter is not used a message box with the Ok button and no icon is displayed. See the next section for more about this parameter.

title[optional] – this is the title that will appear at the top of the message box. The default is “Microsoft Excel”.

helpfile, context[optional] – These parameters are used to reference a help file and location of specific help text. It is very unlikely you use this unless you are creating an application for a third party and help files are a requirement.

 

VBA MsgBox Return Values

The following are all the return values for the MsgBox function:

vbOk
vbCancel
vbAbort
vbRetry
vbIgnore
vbYes
vbNo

Each of these values represents a button that was clicked.

 

VBA MsgBox Yes No

We can use the message box to get a simple response from the user. For example, we can ask the user a question and they can respond by clicking on the Yes or No button. The return value from the MsgBox function tells us which button was clicked.

VBA MsgBox

 

If we want to get a Yes/No response from the user we can do it with the following code:

Sub MessagesYesNoWithResponse()

    ' Display a messagebox based on the response
    If MsgBox("Do you wish to continue? ", vbYesNo) = vbYes Then
        MsgBox "The user clicked Yes"
    Else
        MsgBox "The user clicked No"
    End If

End Sub

 

Note: When we return a value from the message box we must use parenthesis around the parameters or we will get the “Expected end of statement” error.

 

We can also use a variable to store the response from the MsgBox. We would normally do this if we want to use the response more than once. For example, if there were three buttons:

Sub Msgbox_AbortRetryIgnore()

    Dim resp As VbMsgBoxResult
    ' Store MsgBox response in a variable
    resp = MsgBox("Do you wish to continue? ", vbAbortRetryIgnore)
    
    ' Display Ok/Cancel buttons and get response
    If resp = vbAbort Then
        MsgBox "The user clicked Abort"
    ElseIf resp = vbRetry Then
        MsgBox "The user clicked Retry"
    ElseIf resp = vbIgnore Then
        MsgBox "The user clicked Ignore"
    End If

End Sub

 

VBA MsgBox Button Parameters

The button parameter of MsgBox allows us to configure the message box in many ways. The table below shows the different options:

ConstantGroupTypeDescription
vbOKOnly1ButtonsOk button.
vbOKCancel1ButtonsOk and cancel buttons.
vbAbortRetryIgnore1ButtonsAbort, Retry and Ignore buttons.
vbYesNoCancel1ButtonsYes, No and Cancel buttons.
vbYesNo1ButtonsYes and No buttons.
vbRetryCancel1ButtonsRetry and Cancel buttons.
vbCritical2IconCritical Message icon.
vbQuestion2IconWarning Query icon.
vbExclamation2IconWarning Message icon.
vbInformation2IconInformation Message icon.
vbDefaultButton13Default buttonSet button 1 to be selected.
vbDefaultButton23Default buttonSet button 2 to be selected.
vbDefaultButton33Default buttonSet button 3 to be selected.
vbDefaultButton43Default buttonSet button 4 to be selected. Note that there will only be four buttons if the help button is included with vbAbortRetryIgnore or vbYesNoCancel.
vbApplicationModal4ModalCannot access Excel while the button is displayed. Msgbox is only displayed when Excel is the active application.
vbSystemModal4ModalSame as vbApplicationModal but the message box is displayed in front of all applications.
vbMsgBoxHelpButton5OtherAdds a help button
vbMsgBoxSetForeground5OtherSets the message box windows to be the foreground window
vbMsgBoxRight5OtherRight aligns the text.
vbMsgBoxRtlReading5OtherSpecifies text should appear as right-to-left reading on Hebrew and Arabic systems.

These constants work as follows:

  1. The constants in group 1 are used to select the buttons.
  2. The constants in group 2 are used to select icons.
  3. The constants in group 3 are used to select which button is highlighted when the message box appears.
  4. The constants in group 4 are used to set the modal type of the message box.
  5. The constants in group 5 are used for various settings.

 

When we use MsgBox, we can combine items from each group by using the plus sign. For example:

MsgBox "Example 1" ,vbOkCancel + vbCritical + vbDefaultButton1 + vbApplicationModal

This displays the message box with the Ok and Cancel button, the critical message icon, with the Ok button highlighted and the message box will display only when Excel is the active application.

 

MsgBox "Example 2", vbYesNo + vbQuestion + vbDefaultButton2 + vbSystemModal

This displays the message box with the Yes and No button, the warning query icon, with the No button highlighted and the message box will display in front of all applications.

 

Important: Each time we use the MsgBox function we can only select one of each:

  1. button type
  2. icon type
  3. default button
  4. modal type

In other words, we can only select one item from each of the first 4 groups.

The next section shows some more examples of using the message box.

 

VBA MsgBox Examples

The following examples show to display the various icons with the Yes and No buttons:

  ' Yes/No buttons with Critical icon and No button selected
 resp = MsgBox("Do you wish to continue", vbYesNo + vbCritical)
 
 ' Yes/No buttons with Warning Query icon and Yes button selected
 resp = MsgBox("Do you wish to continue", vbYesNo + vbQuestion)
 
 ' Yes/No buttons with Warning Message icon and Yes button selected
 resp = MsgBox("Do you wish to continue", vbYesNo + vbExclamation)

 ' Yes/No button with Information Message icon and Cancel button selected
 resp = MsgBox("Do you wish to continue", vbYesNo + vbInformation)

 

 

The following examples show the Abort/Retry/Ignore button plus the help button with different buttons selected:

' Abort/Retry/Ignore button with the Help button displayed and Abort selected
resp = MsgBox("Error", vbAbortRetryIgnore + vbDefaultButton1 + vbMsgBoxHelpButton)

' Abort/Retry/Ignore button with the help button displayed and Retry selected
resp = MsgBox("Error", vbAbortRetryIgnore + vbDefaultButton2 + vbMsgBoxHelpButton)

' Abort/Retry/Ignore button with the Help button displayed and Ignore selected
resp = MsgBox("Error", vbAbortRetryIgnore + vbDefaultButton3 + vbMsgBoxHelpButton)

' Abort/Retry/Ignore button with the Help button displayed and Help selected
resp = MsgBox("Error", vbAbortRetryIgnore + vbDefaultButton4 + vbMsgBoxHelpButton)

 

 

The following examples show some button selections and the title parameter being set:

' Retry/Cancel button with query warning as the icon and "Error" as the title
resp = MsgBox("An error occurred. Try again?", vbRetryCancel + vbQuestion, "Error")

' Ok button with critical icon and "System error" as the title
MsgBox "An error occurred", vbCritical, "System Error"

 

 
 

What’s Next?

Free VBA Tutorial If you are new to VBA or you want to sharpen your existing VBA skills then why not try out the The Ultimate VBA Tutorial.

Related Training: Get full access to the Excel VBA training webinars and all the tutorials.

(NOTE: Planning to build or manage a VBA Application? Learn how to build 10 Excel VBA applications from scratch.)

 

Get the Free eBook

How To Ace the 21 Most Common Questions in VBA

Please feel free to subscribe to my newsletter and get exclusive VBA content that you cannot find here on the blog, as well as free access to my eBook, How to Ace the 21 Most Common Questions in VBA which is full of examples you can use in your own code.

Free VBA eBook


5 comments

  1. Is it possible to define alternative text that goes into the buttons, even though they would act as vbYesNo still?
    I’m working on a macro to copy charts and ranges to PowerPoint from Excel.
    I want 2 options, one to copy and paste them as they are on new blank sheets, or for the user to be able to use a control sheet where each chart/range gets pasted to a particular slide and resized according to what’s on the control page.
    I could use a vbYesNo message box but would like to specify the text on the buttons rather than say would you like to use a control page Yes or No

    1. Hi Johnny,

      If you want to configure more than the basic options then you need to create your own message box using UserForms.

      -Paul

  2. The button text for MsgBox is hardcoded and associated with each of the “vb” constants (e.g., vbOKOnly) that Paul mentioned in his article.

    As far as I know, if you want full control over button text, you will need to create your own dialog/message box via a UserForm object.

  3. If you use MsgBox a lot, have a need to clarify to the end-user what the buttons pertain to, or need a way to know what button was pressed to control the flow of processing, you may want to package MsgBox into a function. Below is a VBScript example of a function named AskUser() that I wrote and use in my scripts.

    The variable name prefixes (e.g., int, lng, str) should give you a clue as to the VBA datatypes to use. WScript.Quit() is not appropriate for VBA code.

    ‘I am only showing definitions for the main variables that are needed
    ‘to interface directly with the AskUser() function below
    Dim lngButtons
    Dim strPrompt
    Dim strTitle
    Dim intSelection

    ‘The following code snippet references other variables (intExitErrorLevel,
    ‘lngInx, lngMetricFilesHidden, lngMetricFilesDeleted) and
    ‘objects (dictHiddenFiles, objFile)

    strPrompt = “FILE” & vbCrLf & _
    ” ” & dictHiddenFiles.Keys()(lngInx – 1) & vbCrLf & vbCrLf & _
    “TYPE” & vbCrLf & _
    ” ” & objFile.Type & vbCrLf & vbCrLf & _
    “Click Cancel to exit script.”

    lngButtons = vbYesNoCancel + vbQuestion + vbDefaultButton2

    strTitle = “Delete this hidden file?” & ” (” & lngInx & ” of ” & lngMetricFilesHidden & “)”

    intSelection = AskUser(strPrompt, lngButtons, strTitle)

    Select Case intSelection
    Case vbCancel
    WScript.Quit(intExitErrorLevel)

    Case vbYes
    lngMetricFilesDeleted = lngMetricFilesDeleted + 1

    objFile.Delete(True)

    Case vbNo
    ‘Ignore — do nothing

    Case Else
    MsgBox _
    “Unexpected user response of ” & intSelection & _
    ” was received.” & _
    “”, vbOKOnly, “Error”
    WScript.Quit(intExitErrorLevel)
    End Select

    Function AskUser(ByVal strPrompt, _
    ByVal lngButtons, _
    ByVal strTitle)

    AskUser = MsgBox(strPrompt, lngButtons, strTitle)
    End Function

Leave a Reply

Your email address will not be published. Required fields are marked *