VBA Tutorial – The Ultimate Guide for Beginners

VBA Tutorial

Welcome to part one of the Ultimate VBA Tutorial for beginners.

If you are brand new to VBA, then make sure that you have read the post How To Create a Macro From Scratch in Excel so that your environment is set up correctly to run macros.

In this Excel VBA tutorial you will learn how to create real-world macros. The focus is on learning by doing. This tutorial has coding examples and activities to help you on your way. You will find a quiz at the end of this VBA tutorial. You can use this to test your knowledge and see how much you have learned.

In part one of this VBA tutorial we will concentrate on the basics of creating Excel macros. See the next sections for the learning outcomes and for tips on getting started with VBA.


“The noblest pleasure is the joy of understanding.” – Leonardo da Vinci


Learning Outcomes for this VBA Tutorial

When you finish this VBA tutorial you will be able to:

  1. Create a module
  2. Create a sub
  3. Understand the difference between a module and sub
  4. Run the code in a sub
  5. Write a value to a cell
  6. Copy the value from one cell to another
  7. Copy values from one range of cells to another
  8. Copy values between difference worksheets
  9. Test your output using the Immediate Window
  10. Write code faster using the With Statement
  11. Create and use variables
  12. Copy from a cell to a variable and vice versa


Before we get started, let’s look at some simple tips that will help you on your journey.

The Six Killer Tips For This VBA Tutorial

  1. Practice, Practice, Practice – Don’t try to learn by reading. Try the examples and activities.
  2. Type the code examples instead of copying and pasting – this will help you understand the code better.
  3. Have a clearly defined target for learning VBA. One you will know when you reach.
  4. Don’t be put off by errors. They help you write proper code.
  5. Start by creating simple macros for your work. Then create more complex ones as you get better.
  6. Don’t be afraid to work through each tutorial more than once.The more times you do it the more deeply embedded the knowledge will become.


Basic Terms Used in this VBA Tutorial

Excel Macros: A macro is a group of programming instructions we use to create automated tasks.

VBA: VBA is the programming language we use to create macros. It is short for Visual Basic for Applications.

Line of code: This a VBA instruction. Generally speaking, they perform one task.

Sub: A sub is made up of one or more lines of code. When we “Run” the sub, VBA goes through all the lines of code and carries out the appropriate actions. A macro and a sub are essentially the same thing.

Module: A module is simply a container for our subs. A module contains subs which in turn contain lines of code. There is no limit(within reason) to the number of modules in a workbook or the number of subs in a module.

VBA Editor: This is where we write our code. Pressing Alt + F11 switches between Excel and the Visual Basic Editor. If the Visual Basic editor is not currently open then pressing Alt + F11 will automatically open it.


The screenshot below shows the main parts of the Visual Basic Editor:

The Visual Basic Editor


Tip for the VBA Tutorial Activities

When you are working on the activities in this VBA Tutorial it is a good idea to close all other Excel workbooks.


Creating a Module

In Excel, we use the VBA language to create macros. VBA stands for Visual Basic for Applications.

When we use the term Excel Macros we are referring to VBA. The term macro is essentially another name for a sub. Any time you see the terms Excel Macros or VBA just remember they are referring to the same thing.

In VBA we create lines of instructions for VBA to process. We place the lines of code in a sub. These subs are stored in modules.

We can place our subs in the module of the worksheet. However, we generally only place code for worksheet events here.

In VBA, we create new modules to hold most of our subs. So for our first activity let’s go ahead and create a new module.


 Activity 1


  1. Open a new blank workbook in Excel.
  2. Open the Visual Basic Editor(Alt + F11).
  3. Go to the Project – VBAProject window on the left(Ctrl + R if it is not visible).
  4. Right-click on the workbook and click Insert and then Module.
  5. Click on Module1 in the Project – VBAProject window.
  6. In the Properties window in the bottom left(F4 if not visible), change the module name from module1 to MyFirstModule.



 End of Activity 1

The module is where you place your code. It is simply a container for code and you don’t use it for anything else.

You can think of a module like a section in a bookshop. It’s sole purpose is to store books and having similar books in a particular section makes the overall shop more organised.

The main window(or code window) is where the code is written. To view the code for any module including the worksheets you can double-click on the item in the Project – VBAProject window.

Let’s do this now so you can become familiar with the code window.


 Activity 2


  1. Open a new workbook and create a new module like you did in the last activity.
  2. Double-click on the new module in the Project – VBAProject window.
  3. The code window for this module will open. You will see the name in the title bar of Visual Basic.


VBA Tutorial 2A


 End of Activity 2

You can have as many modules as you like in a workbook and as many subs as you like within a module. It’s up to you how you want to name the modules and how you organize your subs within your modules.

In the next part of this VBA Tutorial, we are going to look at using subs.

How to Use Subs

A line of code is the instruction(s) we give to VBA. We group the lines of code into a sub. We place these subs in a module.

We create a sub so that VBA will process the instructions we give it. To do this we get VBA to Run the sub. When we select Run Sub from the menu, VBA will go through the lines of code in the sub and process them one at a time in the order they have been placed.

Let’s go ahead and create a sub. Then afterward, we will have a look at the lines of code and what they do.


 Activity 3


  1. Take the module you created in the last activity or create a new one.
  2. Select the module by double-clicking on it in the Project – VBAProject window. Make sure the name is visible in the title bar.
  3. Enter the following line in the code window and press enter.
    Sub WriteValue


  4. VBA will automatically add the second line End Sub. We place our code between these two lines.
  5. Between these two lines enter the line
     Sheet1.Range("A1") = 5

    You have created a sub! Let’s take it for a test drive.

  6. Click in the sub to ensure the cursor is placed there. Select Run->Run Sub/Userform from the menu(or press F5).
    Note: If you don’t place the cursor in the sub, VBA will display a list of available subs to run.
  7. Open Excel(Alt + F11). You will see the value 5 in the cell A1.
  8. Add each of the following lines to your sub, run the sub and check the results.


Sheet1.Range("B1") = "Some text"
Sheet1.Range("C3:E5") = 5.55
Sheet1.Range("F1") = Now

You should see “Some text” in cells B1, 5.55 in the cells C3 to E5 and the current time and date in the cell F1.


 End of Activity 3


Writing values to cells

Let’s look at the line of code we used in the previous section of this VBA Tutorial

Sheet1.Range("A1") = 5

We can also write this line like this

Sheet1.Range("A1").Value = 5

However in most cases we don’t need to use Value as this is the default property.

We use lines of code like these to assign(.i.e. copy) values between cells and variables.

VBA evaluates the right of the equals sign and places the result in the variable/cell/range that is to the left of the equals.

The line is saying “the left cell\variable\range will now be equal to the result of the item on the right”.

Tutorial 1 Assignment line parts

Let’s look the part of the code to the left of the equals sign

Sheet1.Range("A1") = 5

In this code , Sheet1 refers to the code name of the worksheet. We can only use the code name to reference worksheets in the workbook containing the code. We will look at this in the section The code name of the worksheet.

When we have the reference to a worksheet we can use the Range property of the worksheet to write to a range of one or more cells.

Using a line like this we can copy a value from one cell to another.


Here are some more examples:

' https://excelmacromastery.com/
Sub CopyValues()
    ' copies the value from C2 to A1
    Sheet1.Range("A1") = Sheet1.Range("C2")
    ' copies the value from D6 to A2
    Sheet1.Range("A2") = Sheet1.Range("D6")
    ' copies the value from B1 on sheet2 to A3 on sheet1
    Sheet1.Range("A3") = Sheet2.Range("B1")
    ' writes result of D1 + D2 to A4
    Sheet1.Range("A4") = Sheet2.Range("D1") + Sheet2.Range("D2")
End Sub


Now it’s your turn to try some examples. Copying between cells is a fundamental part of Excel VBA, so understanding this will really help you on your path to VBA mastery.

 Activity 4


      1. Create a new Excel workbook.
      2. Manually add values to the cells in sheet1 as follows: 20 to C1 and 80 to C2.
      3. Create a new sub called Act4.
      4. Write code to place the value from C1 in cell A1.
      5. Write code to place the result of C2 + 50 in cell A2.
      6. Write code to multiply the values in cells C1 and C2. Place the results in cell A3.
      7. Run the code. Cells should have the values A1 20, A2 130 and A3 1600



 End of Activity 4


Cells in Different Sheets

We can easily copy between cells on different worksheets. It is very similar to how we copy cells on the same worksheet. The only difference is the worksheet names which we use in our code.

In the next VBA Tutorial activity, we are going to write between cells on different worksheets.


 Activity 5


      1. Add a new worksheet to the workbook from the last activity. You should now have two worksheets called which are called Sheet1 and Sheet2.
      2. Create a new sub call Act5.
      3. Add code to copy the value from C1 on Sheet1 to cell A1 on Sheet2.
      4. Add code to place the result from C1 + C2 on Sheet1 to cell A2 on Sheet2.
      5. Add code to place the result from C1 * C2 on Sheet1 to cell A3 on Sheet2.
      6. Run the code in the sub(F5). Cells on Sheet2 should have the values as follows:
        A1 20, A2 100 and A3 1600


 End of Activity 5


The Code Name of the Worksheet

In the activities so far, we have been using the default names of the worksheet such as Sheet1 and Sheet2. It is considered good practice to give these sheets more meaningful names.

We do this by changing the code name of the worksheet. Let’s look at the code name and what it is.

When you look in the Project – VBAProject window for a new workbook you will see Sheet1 both inside and outside of parenthesis:


VBA Code name


      • Sheet1 on the left is the code name of the worksheet.
      • Sheet1 on the right(in parenthesis) is the worksheet name. This is the name you see on the tab in Excel.

The code name has the following attributes

      1. We can use it to directly reference the worksheet as we have been doing e.g.



Note: We can only use the code name if the worksheet is in the same workbook as our code.

      1. If the worksheet name is changed our code will still work if we are using the code name to refer to the sheet.

The worksheet name has the following attributes

      1. To reference the worksheet using the worksheet name we need to use the worksheets collection of the workbook. e.g.




      1. If the worksheet name changes then we need to change the name in our code. For example, if we changed the name of our sheet from Sheet1 to Data then we would need to change the above code as follows



We can only change the code name in the Properties window.
We can change the worksheet name from both the worksheet tab in Excel and from the Properties window.


VBA Code name



worksheet name on tab

In the next activity we will change the code name of the worksheet.

 Activity 6


      1. Open a new blank workbook and go to the Visual Basic editor.
      2. Click on Sheet1 in the Project – VBAProject Window(Ctrl + R if not visible).
      3. Go to the Properties window(F4 if not visible).
      4. Change the code name of the worksheet to shReport.
      5. Create a new module and call it modAct6.
      6. Add following sub and run it(F5)


Sub UseCodename()
    shReport.Range("A1") = 66
End Sub


      1. Then add following sub and run it(F5)


Sub UseWorksheetname()
    ThisWorkbook.Worksheets("Sheet1").Range("B2") = 55
End Sub


      1. Cell A1 should now have the value 66 and cell B2 should have the value 55.
      2. Change the name of the worksheet in Excel to Report i.e. right-click on the worksheet tab and rename.
      3. Delete the contents of the cells and run the UseCodename code again. The code should still run correctly.
      4. Run the UseWorksheetname sub again. You will get the error “Subscript out of Range”. This crytically sounding error simply means that there is no worksheet called Sheet1 in the worksheets collection.
      5. Change the code as follows and run it again. The code will now run correctly.


Sub UseWorksheetname()
    ThisWorkbook.Worksheets("Report").Range("B2") = 55
End Sub


 End of Activity 6



The With keyword

You may have noticed in this VBA Tutorial that we need to use the worksheet name repeatedly – each time we refer to a range in our code.

Imagine there was a simpler way of writing the code. Where we could just mention the worksheet name once and VBA would apply to any range we used after that. The good news is we can do exactly that using the With statement.

In VBA we can take any item before a full stop and use the With statement on it. Let’s rewrite some code using the With statement.

The following code is pretty similar to what we have been using so far in this VBA Tutorial:

' https://excelmacromastery.com/
Sub WriteValues()

    Sheet1.Range("A1") = Sheet1.Range("C1")
    Sheet1.Range("A2") = Sheet1.Range("C2") + 50
    Sheet1.Range("A3") = Sheet1.Range("C1") * Sheet1.Range("C2")
End Sub


Let’s update this code using the With statement:

' https://excelmacromastery.com/
Sub UsingWith()

    With Sheet1
        .Range("A1") = .Range("C1")
        .Range("A2") = .Range("C2") + 50
        .Range("A3") = .Range("C1") * .Range("C2")
    End With
End Sub


We use With and the worksheet to start the section. Anywhere VBA finds a full stop it knows to use the worksheet before it.

We can use the With statement with other types of objects in VBA including workbooks, ranges, charts and so on.

We signify the end of the With section by using the line End With.

Indenting(Tabbing) the Code
You will notice that the lines of code between the start and end With statments are tabbed once to right. We call this indenting the code.

We always indent the code between VBA sections that have a starting line and end line. Examples of these are as subs, the With statement, the If statement and the For loop.

You can tab the lines of code to the right by selecting the appropriate lines of code and pressing the Tab key. Pressing Shift and Tab will tab to the left.

Tabbing(or indenting) is useful because it makes our code more readable.


 Activity 7


      1. Rewrite the following code using the With statement. Don’t forget to indent the code.


' https://excelmacromastery.com/
Sub UseWith()

Sheet1.Range("A1") = Sheet1.Range("B3") * 6
Sheet1.Cells(2, 1) = Sheet1.Range("C2") + 50
Sheet1.Range("A3") = Sheet2.Range("C3")

End Sub



 End of Activity 7


Copying values between multiple cells

You can copy the values from one range of cells to another range of cells as follows

Sheet2.Range("A1:D4") = Sheet2.Range("G2:I5").Value


It is very important to notice than we use the Value property of the source range. If we leave this out it will write blank values to our destination range.

' the source cells will end up blank because Value is missing
Sheet2.Range("A1:D4") = Sheet2.Range("G2:I5")


The code above is a very efficient way to copy values between cells. When people are new to VBA they often think they need to use some form of select, copy and paste to copy cell values. However these are slow, cumbersome and unnecessary.

It is important that both the destination and source ranges are the same size.

      • If the destination range is smaller then only cell in the range will be filled. This is different to copy/pasting where we only need to specify the first destination cell and Excel will fill in the rest.
      • If the destination range is larger the extra cells will be filled with #N/A.


 Activity 8


      1. Create a new blank workbook in Excel.
      2. Add a new worksheet to this workbook so there are two sheets – Sheet1 and Sheet2.
      3. Add the following data to the range C2:E4 on Sheet1

VBA Tutorial Act 7

      1. Write code to copy the data from Sheet1 to the range B3:D5 on Sheet2.
      2. Run the code(F5).
      3. Clear the results and then change the destination range to be smaller than the source range. Run again and check the results.
      4. Clear the results and then change the destination range to be larger than the source range. Run again and check the results.


 End of Activity 8


Transposing a Range of Cells

If you need to transpose the date(convert from row to column and vice versa) you can use the WorksheetFunction Transpose.

Place the values 1 to 4 in the cells A1 to A4. The following code will write the values to E1 to H1

Sheet1.Range("E1:H1") = WorksheetFunction.Transpose(Sheet1.Range("A1:A4").Value)


The following code will read from E1:H1 to L1:L4

Sheet1.Range("L1:L4") = WorksheetFunction.Transpose(Sheet1.Range("E1:H1").Value)


You will notice that these lines are long. We can split one line over multiple lines by using the underscore(_) e.g.

Sheet1.Range("E1:H1") = _ 
Sheet1.Range("L1:L4") = _


How to Use Variables

So far in this VBA Tutorial we haven’t used variables. Variables are an essential part of every programming language.

So what are they and why do you need them?

Variables are like cells in memory. We use them to store temporary values while our code is running.

We do three things with variables

      1. Declare(i.e. Create) the variable.
      2. Store a value in the variable.
      3. Read the value stored in the variable.

The variables types we use are the same as the data types we use in Excel.

The table below shows the common variables. There are other types but you will rarely use them. In fact you will probably use Long and String for 90% of your variables.

BooleanCan be true or false only
Currencysame as decimal but with 4 decimal places only
DateUse for date/time
DoubleUse for decimals
Long Use for integers
StringUse for text
VariantVBA will decide the type at runtime


Declaring Variables

Before we use variables we should create them. If we don’t then we can run into various problems.

By default, VBA doesn’t make you declare variables. However, we should turn this behaviour on as it will save us a lot of pain in the long run.

To turn on “Require Variable Declaration” we add the following line to the top of our module

Option Explicit

To get VBA to automatically add this line, select Tools->Options from the menu and check Require Variable Declaration. Anytime you create a new module, VBA will add this line to the top.

VBA Option Explicit

Declaring a variable is simple. We use the format as follows

Dim variable_name As Type


We can use anything we like as the variable name. The type is one of the types from the table above. Here are some examples of declarations

Dim Total As Long
Dim Point As Double
Dim Price As Currency
Dim StartDate As Date
Dim CustomerName As String
Dim IsExpired As Boolean
Dim Item As Variant


To place a value in a variable we use the same type of statement we previously used to place a value in a cell. That is, the statement with the equals sign.

' https://excelmacromastery.com/
Sub DeclaringVars()

    Dim Total As Long
    Total = 1
    Dim Price As Currency
    Price = 29.99
    Dim StartDate As Date
    StartDate = #1/21/2018#
    Dim CustomerName As String
    CustomerName = "John Smith"
End Sub


 Activity 9


      1. Create a new sub and call it UsingVariables.
      2. Declare a variable for storing a count and set the value to 5.
      3. Declare a variable for storing the ticket price and set the value to 99.99.
      4. Declare a variable for storing a country and set the value to “Spain”.
      5. Declare a variable for storing the end date and set the value to 21st March 2020.
      6. Declare a variable for storing if something is completed. Set the value to False.


 End of Activity 9


The Immediate Window

VBA has a real nifty tool that allows us to check our output. This tool is the Immediate Window. By using the Debug.Print we can write values, text and results of calculations to the Immediate Window.

To view this window you can select View->Immediate Window from the menu or press Ctrl + G.

The values will be written even if the Immediate Window is not visible.



We can use the Immediate Window to write out our variables so as to check the values they contain.

If we update the code from the last activity we can write out the values of each variable. Run the code below and check the result in the Immediate Window(Ctrl + G if not visible).

' https://excelmacromastery.com/
Sub WritingToImmediate()
    Dim count As Long
    count = 5
    Debug.Print count
    Dim ticketprice As Currency
    ticketprice = 99.99
    Debug.Print ticketprice
    Dim country As String
    country = "Spain"
    Debug.Print country
    Dim enddate As Date
    enddate = #3/21/2020#
    Debug.Print enddate
    Dim iscompleted As Boolean
    iscompleted = False
    Debug.Print iscompleted
End Sub

The Immediate is very useful for testing output before we write it to worksheets. We will be using it a lot in these tutorials.


Writing between variables and cells

We can write and read values between cells and cells, cells and variables,and variables and variables using the assignment line we have seen already.

Here are some examples

' https://excelmacromastery.com/
Sub VariablesCells()

    Dim price1 As Currency, price2 As Currency
    ' place value from A1 to price1
    price1 = Sheet1.Range("A1")
    ' place value from price1 to price2
    price2 = price1
    ' place value from price2 to cell b2
    Sheet1.Range("B2") = price2
    ' Print values to Immediate window
    Debug.Print "Price 1 is " & price1
    Debug.Print "Price 2 is " & price2

End Sub



 Activity 10


      1. Create a blank workbook and a worksheet so it has two worksheets: Sheet1 and Sheet2.
      2. Place the text “New York” in cell A1 on Sheet1. Place the number 49 in cell C1 on Sheet2.
      3. Create a sub that reads the values into variables from these cells.
      4. Add code to write the values to the Immediate window.


 End of Activity 10


Type Mismatch Errors

You may be wondering what happens if you use an incorrect type. For example, what happens if you read the number 99.55 to a Long(integer) variable type.

What happens is that VBA does it best to convert the variable. So if we assign the number 99.55 to a Long type, VBA will convert it to an integer.

In the code below it will round the number to 100.

Dim i As Long
i = 99.55


VBA will pretty much convert between any number types e.g.

' https://excelmacromastery.com/
Sub Conversion()

    Dim result As Long
    result = 26.77
    result = "25"
    result = 24.55555
    result = "24.55"  
    Dim c As Currency
    c = 23
    c = "23.334"
    result = 24.55
    c = result

End Sub


However, even VBA has it’s limit. The following code will result in Type Mismatch errors as VBA cannot convert the text to a number

' https://excelmacromastery.com/
Sub Conversion()

    Dim result As Long
    result = "26.77A"
    Dim c As Currency
    c = "a34"

End Sub


Tip: The Type Mismatch error is often caused by a user accidently placing text a cell that should have numeric data.


 Activity 11


      1. Declare a Double variable type called amount.
      2. Assign a value the causes a Type Mismatch error.
      3. Run the code and ensure the error occurs.


 End of Activity 11


End of VBA Tutorial Assignment

We’ve covered a lot of stuff in this tutorial. So let’s put it all together in the following assignment


 Tutorial One Assignment

I have created a simple workbook for this assignment. You can download it using the link below

Tutorial One Assignment Workbook

Open the assignment workbook. You will place your code here

      1. Create a module and call it Assignment1.
      2. Create a sub called Top5Report to write the data in all the columns from the top 5 countries to the Top 5 section in the Report worksheet. This is the range starting at B3 on the Report worksheet. Use the code name to refers to the worksheets.
      3. Create a sub call AreaReport to write all the areas size to the All the Areas section in the Report worksheet. This is the range H3:H30. Use the worksheet name to refer to the worksheets.
      4. Create a sub called ImmediateReport as follows, read the area and population from Russia to two variables. Print the population per square kilometre(pop/area) to the Immediate Window.
      5. Create a new worksheet and call it areas. Set the code name to be shAreas. Create a sub called RowsToCols that reads all the areas in D2:D11 from Countries worksheet and writes them to the range A1:J1 in the new worksheet Areas.



End of Tutorial Assignment


The following quiz is based on what we covered this tutorial.

VBA Tutorial One Quiz

1. What are the two main differences between the code name and the worksheet name?


2. What is the last line of a Sub?


3. What statement shortens our code by allowing us to write the object once but refer to it multiple times?


4. What does the following code do?


Sheet1.Range("D1") = result



5. What does the following code do?


Sheet1.Range("A1:C3") = Sheet2.Range("F1:H3")



6. What is the output from the following code?


Dim amount As Long
amount = 7

Debug.Print (5 + 6)  * amount  



7. What is the output from the following code?


Dim amt1 As Long, amt2 As Long

amt1 = "7.99"
Debug.Print amt1

amt2 = "14a"
Debug.Print amt2



8. If we have 1,2 and 3 in the cells A1,A2 and A3 respectively, what is the result of the following code?


Sheet1.Range("B1:B4") = Sheet1.Range("A1:A3").Value



9. What does the shortcut key Alt + F11 do?




10. In the following code we declare a variable but do not assign it a value. what is the output of the Debug.Print statement?


Dim amt As Long

Debug.Print amt




Conclusion of the VBA Tutorial Part One

Congratulations on finishing tutorial one. If you have completed the activities and the quiz then you will have learned some important concepts that will stand to you as you work with VBA.

In the Tutorial 2, we are going to deal with ranges where the column or row may differ each time the application runs. In this tutorial, we will cover

      • How to get the last row or column with data.
      • The amazingly efficient CurrentRegion property.
      • How to use flexbile rows and columns.
      • When to use Range and when to use Cells.
      • and much more…


Please note: that Tutorials 2 to 4 can be purchased by members of my email list at a specially discounted price.

You can can sign up to the email list here.


What’s Next?

Planning to build or manage a VBA Application? Learn how to build 10 Excel VBA applications from scratch.


  1. Hay Paul

    thankyou for this handbook it has taught practicalities of this coding system

    but i have a question in relation to the premium handbook is it any different to the website content?


    1. Hi Kristian,

      The Excel VBA Handbook has a lot of content that isn’t available on the website. The website deals with individual topics – the handbook teaches how to build full applications.


  2. Paul, Thanks for your effort. I already purchased your Udemy course Excel VBA: How to Write Macros Like a Professional and have gone through it. Whats the difference between this udemy course and your VBA premium handbook. Or if there is a difference then could you create a Udemy course of your VBA premium handbook, which will be easier for people to buy it.

    1. Hi Pradeep,

      The Udemy course is aimed at complete beginners and teaches professional real-world techniques for using VBA.

      The Excel VBA Handbook teaches the user to build real-world VBA applications. There are 10 applications which include guides, source code and video workshops.

  3. Hi Paul

    When ‘Copying values between multiple cells’, I have found your method many times faster that copy and paste. However, where the source is text but look like numbers, e.g. “01” the leading zero are dropped.

    I am not sure how best to overcome this, but a web search suggested modifying:

    Sheet1.Range(“B1:B4”) = Sheet1.Range(“A1:A3”).Value

    to become:

    Sheet1.Range(“B1:B4”).value(11) = Sheet1.Range(“A1:A3”).Value(11)

    Or it may be easier to stick to using the .copy approach?

  4. What is the assignment Range in Activity 8? It was not referenced earlier in the documentation, I think that would be valuable to clarify either earlier or in that activity.

    1. I have changed “assignment” to “destination” to make it clearer. Thanks for pointing that out.

  5. Along with my previous comment, in activity 8 if your Assignment range is larger than your source range you receive #N/A errors, is that the same as =NA(), or is it merely appear the same?

  6. Hi Paul, thanks for coming up with this Tutorial.

    In Assignment 1 solution part 5 requiring transpose worksheet function, “.value” is missing on the right-hand side.

    1. Hi Scott,

      It will still work fine as value is considered the default property of the range.

      However, I have updated the code with value to avoid confusion.


  7. The link you reference in the beginning of the article about creating a macro from scratch is somewhat broken. As is, it doesn’t work (and hung the browser the first time), but it looks like it’s just not working under https. It worked with http. Weird

  8. Hi Paul,
    I am looking for more tutorial assignment with sample Code .
    it helps in gaining knowledge. will I able to get it from this website.

    1. There are three more tutorials plus over 40 hours of training and associated workbooks and code.

      They are all available to members of the website.

      You can become a member here

        1. Hi Karthik,

          At the moment there is 4 main tutorials with approx 40 exercises and 4 assignments. I don’t have further exercises but you can work through the applications in the webinars. the come with the full code.

          The next tutorial I do will be around building an application.


  9. Hello Mr. Kelly, I am working with an excel spreadsheet that has 6 sheets – a Personal Log, Letter, ‘FRED'(Federal Reserve Economic Data), ‘Template’, ‘List’ all which is mainly using VLookUp to pull info from each tab after the user inserts the data (i apologize in advance if you don’t understand entirety) at any rate- my assignment is to search through FRED (data) tab and find the 3 specific funds, and if found – I need to send a ‘Indemnification letter’ to the ‘Letter’ tab. I have been practicing your array & if/then tutorials, and have not gotten much luck. Do you think you can direct me to the correct tutorial to help my situation or do you have any other suggestions, guess what I need is kind of an outline or steps to follow…?

    1. Hi Shawn,

      The following sample code, shows how to read through data on a worksheet.


      Sub ReadData()
          ' Get the worksheet
          Dim sh As Worksheet
          Set sh = ThisWorkbook.Worksheets("FRED")
          ' Get range
          Dim rg As Range
          Set rg = sh.Range("A1").CurrentRegion
          ' Read the data
          For i = 2 To rg.Rows.Count
              ' Check value in column 1 of each row
              If rg.Cells(i, 1).Value = "Fund1" Then
                  ' send letter
              End If
          Next i
      End Sub
  10. Hi Paul,

    im trying to code a loop that will take each the first 34 cells of many colums, and stack them underneath the first column. As i dont know how many columns it will apply to in each case, i need it to be a loop that keeps going until the cells are empty.
    I have gotten the code to do as i wish, but it seems to jump out of the loop after finishing 36 columns. I cant find out why it keeps doing that. I would also like some guidence as to what i can do to make the loop end when the cells are empty.

    This is my code:

    Sub test2()
    Dim cell As Variant
    Dim plassering1 As Integer
    Dim plassering2 As Integer
    plassering1 = 68
    plassering2 = -2

    ActiveCell.Offset(0, 1).Range(“A1:A34”).Select
    Selection.Cut Destination:=ActiveCell.Offset(34, -1).Range(“A1:A34”)
    ActiveCell.Offset(0, 1).Range(“A1:A34”).Select
    Selection.Cut Destination:=ActiveCell.Offset(68, -2).Range(“A1:A34”)
    ActiveCell.Offset(68, -2).Range(“A1:A34”).Select

    For Each cell In Selection.Cells
    plassering2 = plassering2 – 1
    ActiveCell.Offset(-plassering1, -plassering2).Range(“A1:A34”).Select
    plassering1 = plassering1 + 34
    Selection.Cut Destination:=ActiveCell.Offset(plassering1, plassering2).Range(“A1:A34”)
    ActiveCell.Offset(plassering1, plassering2).Range(“A1:A34”).Select

    Next cell

    End Sub

    Can you help me please?

    1. A little late, perhaps, but possibly…
      Sub test2()
      Dim LastColumn As Long
      Dim LastRow As Long
      Dim i As Long

      With Sheet1
      LastColumn = .Cells(1, .Columns.Count).End(xlToLeft).Column
      For i = 2 To LastColumn
      LastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
      .Range(.Cells(1, i), .Cells(34, i)).Cut Destination:=.Cells(LastRow, 1)
      Next i
      End With
      End Sub

  11. This is part one. what about other parts of your tutorials in VBA. Does all parts includes the entire VBA.

    1. Hi Pradeep,

      The tutorials cover, dynamic ranges, building a basic VBA application and using the debugging tools for fixing errors and understanding how the code works.

      The videos cover almost every part of VBA that you will need.


  12. Hi Paul,
    I am am absolute beginner of VBA and tried many tutorial sites to start learning VBA but everything seems difficult for me to follow and understand the basics of VBA. Finally, I found your tutorial site. I wonder, why I did’t find your site earlier (I wouldn’t have wasted so much of time ). Anyways, ultimately I find a very useful website to learn VBA. After going through some of the lessons I found its VBA is not quite difficult. Thank you so much for providing such a tutorial site specially for beginners (like Me)

  13. Hello Paul:
    I am trying to use variables in more than one sub. In the example below, I have two separate subs that use the same variables. In my application it is a great advantage to declare the variables in only one sub. Can you give me some code that will do that. Thanks. Doug Watson
    Sub setup_variables()
    Dim Category As String
    Category = “automobile_parts”
    Dim CategoryNum As Integer
    CategoryNum = 1
    End sub

    Sub another_sub()
    Selection.End(xlDown).Offset(1, 0).Select
    ActiveCell.Value = Category
    ActiveCell.Offset(0, 1).Value = CategoryNum
    End sub

  14. Hi Paul,
    Your definition of Sub is incomplete. Sub is an abbreviation for Subroutine. A subroutine is a program that runs within another program. In this case within the application Excel.

  15. Hi paul,
    Just wanted to check. how many more step by step tutorials you have made with assignment, quizzes like ‘The Ultimate VBA tutorial Part One ‘. Also, is making payment via CC to become monthly member is safe, there wouldn’t be any theft of deduction from any other sources. Curently it shows 49US dollar for monthly subscription, can you provide some discount on that !

  16. Paul,
    Thank you for sharing your knowledge of VBA in Excel. Your site is very helpful!!! I did encounter a challenge but wondered if it might be a setting in Excel that I might have clicked? When I attempt to run the script below, I get an error… “Run-time error ‘424’: Object required”. Can you help explain why I’m getting this error and what I can do to correct it? Thank you for your help!

    Sub CopyMultipleCells()
    Sheet2.Range(“B3:D5”) = Sheet1.Range(“C2:E4”).Value
    End Sub

  17. This website is such a great reference for people learning VBA and macros in excel. Thanks so much for doing this. I wish there had been an equivalent VBScript site for the custom outlook form I created a few years back. Keep up the great work!

  18. Hello Paul.
    I have enjoyed reading through your site. I have written the following code:

    Sheet2.Range(“C5”) = Sheet2.Range(“C5”) – Sheet1.Range(“A17”)

    The code works fine. However; I need to do the same for Cells C6:C32 and Cells A18:A44

    Instead of writing 28 lines of code, can this be put in some kind of loop using just the single line and having the cell numbers change?

  19. I submitted the previous post too soon. Please delete it and use this one. I have a workbook that uses a form to intake information from the user (up to 47 fields worth). It then enters it into a worksheet for a specific customer. Each time new information is added, it creates a new row. The 47 fields are each entered into their own column. Another form is used to update existing fields of data, it modifies the existing corresponding row in the customer sheet. There is a summary sheet of all rows (I guess it is known as a flat file). A copy of the same row that goes into the customer sheet is created each time new customer data is entered. The problem is that whenever data is modified, the old data remains behind in the summary sheet, unless I have the user intervene and delete it. This is causing too much confusion and is leading to other rows in the summary sheet getting deleted, and other problems. So, I want to have the summary sheet pull the information from the existing rows across all the sheets in real time. I want it to mirror all the rows across all the sheets with no user interaction needed. I am not sure how to go about this. I have tried an array, and it read through the sheet, but it takes forever. I can watch as it goes through the rows of each sheet displaying the data, but it ends up only keeping the rows from the last worksheet that it looped through. I want all the rows in the workbook added into the summary sheet. Can you point me to a video that explains this or something close enough that I can figure it out? Thank you.

  20. Paul: I have code in Excel VBA that opens a separate password protected Excel file. If the user enters the wrong password, I get the runtime error 1004 with options to end or debug. I want to trap this error so the user does not see it. I don’t want the user to click on debug. I want to show a message box and have the code end. I have been trying for a couple of hours to do this with no luck. Any thoughts?

  21. Hello,
    What’s the advantage of using debug.print and the immediate window instead of locals window and debug mode?
    Thank you!

    1. Hi Sara,

      The Locals windows only shows local variables. You cannot add or change what is shown here.
      The Watch Window allows you to view any variable including calculations and functions.
      The Immediate Window allows you to test the output of your code. You don’t need to debug the code to see the results.


  22. Hello Paul,

    First I would like to start by saying Thank You! I am new with VBA the material provided in the first tutorial was great. I am naturally a thinker, so the why? is very important for me to learn a new concept. I have been looking at different sites and videos and by far yours really hits the mark. Its so easy to follow with your instructions. The assignment and quiz are a bonus to reassure those newly developed skills. I look forward to more great material, Thank you!

  23. Paul, I am not sure that I got the membership to use your all materials including handbook … which looks like aanother course. If I has not paid to get the right using your course, let me know.
    I have some troubles in searching tutorials as I want.

  24. Hi Paul,
    I gone through your website and it has wide range of information about vba.
    from beginners to advanced learners.

  25. Hi Paul
    I am struggling to find a solution. I have multiple variables that needs to be written to a range of cells.
    This is what I have

    Range(“A1”).Value2 = Dat1
    Range(“A2”).Value2 = Dat2
    Range(“A3”).Value2 = Dat3

    Range(“B1”).Value2 = Val1
    Range(“B2”).Value2 = Val2
    Range(“B3”).Value2 = Val3

    Range(“A1:A3”).Value2 = ??????????

    I found a way but it does not work on the newer versions of excel
    Range(“A1:A3”).Value2 = ([“as”; “bs”; “Cd”])
    Range(“A1:A3”).Value2 = ([Dat1, Dat2, Dat3])


    Charl Sieberhagen

Leave a Reply

Your email address will not be published. Required fields are marked *